{
  description = "Konfiguracja wielu maszyn na raz";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable"; # Bleeding edge!
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, home-manager, ... }: 
  let # pomocnicza funkcja
    mk_system = system: hostname: modules: nixpkgs.lib.nixosSystem {
      inherit system;
      modules = [
        { networking.hostName = hostname; }
	# base configuration
        ./base.nix
        # home manager
        home-manager.nixosModules.home-manager {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.users.sasza = import ./home.nix;
        }
      ] ++ modules;
  };
  in {
    nixosConfigurations = {
      nix-latitude = mk_system "x86_64-linux" "nix-latitude" [
      	./hosts/nix-latitude/configuration.nix
	./modules/plasma.nix
        #./modules/network.nix
        #./modules/office.nix
      ];

      nix-gaming = mk_system "x86_64-linux" "nix-gaming" [
      	./hosts/nix-gaming/configuration.nix
	./modules/plasma.nix
        ./modules/gaming.nix
        ./modules/network.nix
        # ./modules/office.nix
        ./modules/3dprint.nix
      ];
    };
  };
}