esp32/esp32h2_water_temp_pump/esp32h2_water_temp_pump.ino

// Copyright 2024 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

/**
 * @brief This example demonstrates Zigbee temperature sensor.
 *
 * The example demonstrates how to use Zigbee library to create a end device temperature sensor.
 * The temperature sensor is a Zigbee end device, which is controlled by a Zigbee coordinator.
 *
 * Proper Zigbee mode must be selected in Tools->Zigbee mode
 * and also the correct partition scheme must be selected in Tools->Partition Scheme.
 *
 * Please check the README.md for instructions and more detailed description.
 *
 * Created by Jan Procházka (https://github.com/P-R-O-C-H-Y/)
 */

#ifndef ZIGBEE_MODE_ED
#error "Zigbee end device mode is not selected in Tools->Zigbee mode"
#endif

#include "Zigbee.h"
#include <OneWireESP32.h>
#include <FastLED.h>

#define TEMP_PIN 10
#define PUMP_PIN 13
#define LED_PIN 8

CRGB leds[1];

/* Zigbee temperature sensor configuration */
#define ANALOG_DEVICE_ENDPOINT_NUMBER 1
#define TEMP_SENSOR_ENDPOINT_NUMBER 10
uint8_t button = BOOT_PIN;

// Optional Time cluster variables
struct tm timeinfo;
struct tm *localTime;
int32_t timezone;

ZigbeeTempSensor zbTempSensor = ZigbeeTempSensor(TEMP_SENSOR_ENDPOINT_NUMBER);
ZigbeeAnalog zbAnalogTemp = ZigbeeAnalog(ANALOG_DEVICE_ENDPOINT_NUMBER);

/************************ Temp sensor *****************************/
const uint8_t MaxDevices = 1;
static float get_temp(int gpio) {
  OneWire32 ds(gpio);
  uint64_t addr[MaxDevices];
  float temp[MaxDevices];
  float avg = 0;
  float num = 0;

  uint8_t devices = ds.search(addr, MaxDevices);

  Serial.printf("Number of devices: %d\r\n", devices);

  ds.request();
	vTaskDelay(800 / portTICK_PERIOD_MS);
  
  for (int i = 0; i < devices; i++) {
    uint8_t err = ds.getTemp(addr[i], temp[i]);
    if (err) {
      const char *errt[] = { "", "CRC", "BAD", "DC", "DRV" };
      Serial.print(i);
      Serial.print(": ");
      Serial.println(errt[err]);
      return err;
    } else {
      avg += temp[i];
      num += 1;
    }
  }
  if (num == 0) return -100.0;
  return avg / num;
}


/************************ Temp sensor ZigBee *****************************/
static void temp_sensor_value_update(void *arg) {
  for (;;) {
    // Read temperature sensor value
    // float tsens_value = temperatureRead();
    float tsens_value = get_temp(TEMP_PIN);

    // Update temperature value in Temperature sensor EP
    if(tsens_value > -50.0 && tsens_value < 150.0) {
      zbTempSensor.setTemperature(tsens_value);
    }

    // check temp and control pump
    if (tsens_value >= zbAnalogTemp.getAnalogOutput() + 5.0 || tsens_value < 0) {  // < 0 for safety if value is uninitialized
      Serial.printf("PUMP ON %.2f°C\r\n", tsens_value);
      digitalWrite(PUMP_PIN, HIGH);
    } else if (tsens_value <= zbAnalogTemp.getAnalogOutput() - 5.0) {
      Serial.printf("PUMP OFF %.2f°C\r\n", tsens_value);
      digitalWrite(PUMP_PIN, LOW);
    }

    delay(1000);
  }
}

/********************* Arduino functions **************************/
void setup() {
  FastLED.addLeds<NEOPIXEL, LED_PIN>(leds, 1);
  leds[0] = CRGB::Red; FastLED.show();

  // Init button switch
  pinMode(button, INPUT_PULLUP);
  pinMode(PUMP_PIN, OUTPUT);
  digitalWrite(PUMP_PIN, HIGH); // default to high just in case

  Serial.begin(115200);
  // while(!Serial);
  leds[0] = CRGB::Orange; FastLED.show();

  // actual temp given by the thermometer
  zbTempSensor.setManufacturerAndModel("ESP32H2", "Furnace Pump");
  zbTempSensor.setMinMaxValue(-10, 125);
  zbTempSensor.setTolerance(0.1);
  zbTempSensor.addTimeCluster();

  // temperature set as the threshold for pump activation/deactivation
  zbAnalogTemp.addAnalogOutput();
  zbAnalogTemp.setAnalogOutputApplication(ESP_ZB_ZCL_AI_TEMPERATURE_OTHER);
  zbAnalogTemp.setAnalogOutputDescription("Water Temperature (°C)");
  zbAnalogTemp.setAnalogOutputResolution(1);
  zbAnalogTemp.setAnalogOutputMinMax(20, 80);

  // Add endpoint to Zigbee Core
  Zigbee.addEndpoint(&zbTempSensor);
  Zigbee.addEndpoint(&zbAnalogTemp);

  leds[0] = CRGB::Yellow; FastLED.show();

  Serial.println("Starting Zigbee...");
  // When all EPs are registered, start Zigbee in End Device mode
  if (!Zigbee.begin()) {
    Serial.println("Zigbee failed to start!");
    Serial.println("Rebooting...");
    ESP.restart();
  } else {
    Serial.println("Zigbee started successfully!");
  }
  
  leds[0] = CRGB::Green; FastLED.show();
  
  Serial.println("Connecting to network");
  while (!Zigbee.connected()) {
    Serial.print(".");
    delay(100);
  }
  Serial.println();

  leds[0] = CRGB::Blue; FastLED.show();

  // Optional: If time cluster is added, time can be read from the coordinator
  timeinfo = zbTempSensor.getTime();
  timezone = zbTempSensor.getTimezone();

  Serial.println("UTC time:");
  Serial.println(&timeinfo, "%A, %B %d %Y %H:%M:%S");

  time_t local = mktime(&timeinfo) + timezone;
  localTime = localtime(&local);

  Serial.println("Local time with timezone:");
  Serial.println(localTime, "%A, %B %d %Y %H:%M:%S");

  // Start Temperature sensor reading task
  xTaskCreate(temp_sensor_value_update, "temp_sensor_update", 3072, NULL, 10, NULL);
  leds[0] = CRGB::White; FastLED.show();

  // Set reporting interval for temperature measurement in seconds, must be called after Zigbee.begin()
  // min_interval and max_interval in seconds, delta (temp change in 0,1 °C)
  // if min = 1 and max = 0, reporting is sent only when temperature changes by delta
  // if min = 0 and max = 10, reporting is sent every 10 seconds or temperature changes by delta
  // if min = 0, max = 10 and delta = 0, reporting is sent every 10 seconds regardless of temperature change
  zbTempSensor.setReporting(10, 300, 1);
  zbAnalogTemp.setAnalogOutput(60.0);  // starting default value

  leds[0] = CRGB::Black; FastLED.show();

}

void loop() {
  // Checking button for factory reset
  if (digitalRead(button) == LOW) {  // Push button pressed
    // Key debounce handling
    delay(100);
    int startTime = millis();
    while (digitalRead(button) == LOW) {
      delay(50);
      if ((millis() - startTime) > 3000) {
        // If key pressed for more than 3secs, factory reset Zigbee and reboot
        Serial.println("Resetting Zigbee to factory and rebooting in 1s.");
        delay(1000);
        Zigbee.factoryReset();
      }
    }
    zbTempSensor.reportTemperature();
  }
  delay(100);
}