wall_h = 35;
wall_t = 5;
t = 5;

doniczka_d = 95;
wall_w = doniczka_d+2*t;
dystans=20;

katownik_h = 32 + 1;
katownik_w = 16 + 1;
katownik_t = 2;
katownik_wciecie = 4.5;

tab = (doniczka_d > 170)?((doniczka_d>240)?[-1, -0.334, 0.334, 1]:[-1,0,1]):[-1,1];

$fn = 360;

difference() {
  union() {
    // wall portion
    translate([-wall_t, -wall_w/2]) cube([wall_t, wall_w, wall_h]);
    // horizontal portion
    translate([0,-wall_w/2,0]) cube([wall_w/2+dystans, wall_w, t]);
    translate([wall_w/2 + dystans,0, 0]) cylinder(d=wall_w, h=t, $fn=100);
  }
  // cutout for metal piece on wall portion
  for(i = tab) {
    translate([-wall_t-0.1, -katownik_w/2 + (i * wall_w/3)])
    union() {
      cube([katownik_t, katownik_w, katownik_h]);
      rotate([0,45+180,0]) translate([-katownik_w/2,0,-katownik_wciecie])
        cube([katownik_w, katownik_w, katownik_w]);
    }
  }
  // planter hole
  translate([wall_w/2 + dystans,0,-0.1]) cylinder(d=doniczka_d, h=t+0.2);
}